home *** CD-ROM | disk | FTP | other *** search
/ Developer CD Series 1995 February: Tool Chest / Dev.CD Feb 95 / Dev.CD Feb 95.toast / Sample Code / Pascal Sample 3.0B10 / Source / Features.inc1.p next >
Encoding:
Text File  |  1993-10-13  |  6.6 KB  |  208 lines  |  [TEXT/MPS ]
  1. (******************************************************************************
  2. *
  3. *    Apple Macintosh Developer Technical Support
  4. *
  5. *    Code for the feature determination routines
  6. *
  7. *    Program:    Sample 3.0
  8. *    File:        Features.inc1.p - Pascal implementation
  9. *
  10. *    by:        Matt Deatherage
  11. *
  12. *    Copyright © 1988-1993 Apple Computer, Inc.
  13. *    All rights reserved.
  14. *
  15. *******************************************************************************
  16.  
  17. {$S Initialize}
  18. (******************************************************************************
  19. *
  20. * private: NumToolboxTraps
  21. *
  22. * This is straight out of Inside Macintosh (Volume VI, pages 3-8 and 3-9).
  23. * It checks to see if setting bit 9 of a toolbox trap (InitGraf, in this
  24. * case) makes a difference in what routine is called.  If it doesn't, there 
  25. * are $200 toolbox traps, but if it does, there are $400 traps.  Used by 
  26. * TrapAvailalble in this unit.
  27. * 
  28. ******************************************************************************)
  29.  
  30. FUNCTION NumToolboxTraps: INTEGER;
  31.  
  32. CONST
  33.     _InitGraf = $A86E;                { Trap number for the InitGraf trap }
  34.  
  35. BEGIN
  36.     IF NGetTrapAddress(_InitGraf, ToolTrap) = NGetTrapAddress($AA6E,
  37.        ToolTrap) THEN
  38.         NumToolboxTraps := $200
  39.     ELSE
  40.         NumToolboxTraps := $400;
  41. END; {NumToolboxTraps}
  42.  
  43. {$S Initialize}
  44. (******************************************************************************
  45. *
  46. * private: GetTrapType
  47. *
  48. * This is straight out of Inside Macintosh (Volume VI, pages 3-8 and 3-9).
  49. * It checks bit eight of a trap instruction to see if it's a Toolbox trap
  50. * or an OS trap.
  51. * 
  52. ******************************************************************************)
  53.  
  54. FUNCTION GetTrapType(theTrap: INTEGER): TrapType;
  55.  
  56. CONST
  57.     TrapMask = $0800;                { Only bit eight is significant }
  58.  
  59. BEGIN
  60.     IF BAND(theTrap, TrapMask) > 0 THEN
  61.         GetTrapType := ToolTrap
  62.     ELSE
  63.         GetTrapType := OSTrap;
  64. END; {GetTrapType}
  65.  
  66. {$S Initialize}
  67. (******************************************************************************
  68. *
  69. * private: TrapAvailable
  70. *
  71. * This is straight out of Inside Macintosh (Volume VI, pages 3-8 and 3-9).
  72. * It checks to see if a given trap is implemented.  The address in the
  73. * trap dispatch tables is compared against the address of the standard
  74. * Unimplemented trap.  If they're the same, the trap is unimplemented.  By
  75. * definition, the trap is also not implemented if it's a Toolbox trap but
  76. * beyond the end of the range of Toolbox traps.  The BOOLEAN result returns
  77. * whether or not the trap is implemented.
  78. * 
  79. ******************************************************************************)
  80.  
  81. FUNCTION TrapAvailable(theTrap: INTEGER): BOOLEAN;
  82.  
  83. CONST
  84.     _Unimplemented = $A89F;
  85.  
  86. VAR
  87.     tType: TrapType;                { the type of theTrap }
  88.  
  89. BEGIN
  90.     tType := GetTrapType(theTrap);
  91.     IF tType = ToolTrap THEN
  92.         BEGIN
  93.             theTrap := BAND(theTrap, $07FF);
  94.             IF theTrap >= NumToolboxTraps THEN
  95.                 theTrap := _Unimplemented;
  96.         END;
  97.     TrapAvailable := NGetTrapAddress(theTrap, tType) <>
  98.                      NGetTrapAddress(_Unimplemented, ToolTrap);
  99. END; {TrapAvailable}
  100.  
  101. {$S Initialize}
  102. (******************************************************************************
  103. *
  104. * Public: DetermineFeatures
  105. *
  106. * DetermineFeatures checks for all the features our application needs.  It
  107. * sets several global variables based on the results and returns TRUE if
  108. * the required features are implemented.  As written here, the only required
  109. * feature is having Gestalt implemented, which lets us check for all the
  110. * rest of the features we want to know about.
  111. *
  112. * Note that in many cases, the check for the _Gestalt trap is unnecessary.
  113. * MPW 3.2 and later link in glue code that always makes Gestalt available.
  114. * If you know your development environment does this, or if you are requiring
  115. * System 6.0.4 or later (highly recommended), you can remove the check for
  116. * Gestalt (as well as NumToolboxTraps, GetTrapType and TrapAvailable unless
  117. * you call them in another place, like we do when checking for DeviceLoop).
  118. * If you remove the calls, remember to set gHasGestalt to TRUE.
  119. * 
  120. ******************************************************************************)
  121.  
  122. FUNCTION DetermineFeatures: BOOLEAN;
  123.  
  124. CONST
  125.     _Gestalt = $A1AD;                { trap number for Gestalt }
  126.     _DeviceLoop = $ABCA;            { trap number for DeviceLoop }
  127.  
  128. VAR
  129.     featureErr: OSErr;                { error variable to use with Gestalt }
  130.     tempResult: LONGINT;            { temporary variable for Gestalt results }
  131.     tempBit: INTEGER;                { temporary variable for bit manipulation:
  132.                                       Pascal doesn't let you pass constants to
  133.                                       library routines like BTST }
  134.                                       
  135. BEGIN
  136.  
  137.     gHasGestalt := TrapAvailable(_Gestalt);
  138.     IF gHasGestalt THEN
  139.         BEGIN
  140.             
  141.             { Check for Balloon Help by testing for the Help Manager }
  142.             
  143.             tempBit := gestaltHelpMgrPresent;
  144.             featureErr := Gestalt(gestaltHelpMgrAttr, tempResult);
  145.             IF featureErr = noErr THEN
  146.                 gHasHelpMgr := BTst(tempResult, tempBit)
  147.             ELSE
  148.                 gHasHelpMgr := FALSE;
  149.  
  150.             { Check for color QuickDraw and 32-bit QuickDraw.  This is to work 
  151.               around a System 7 problem that occasionally makes Gestalt report
  152.               there's color QuickDraw when there isn't.  This method always
  153.               works.  }
  154.             
  155.             featureErr := Gestalt(gestaltQuickdrawVersion, tempResult);
  156.             gHasColorQD := FALSE;
  157.             gHas32BitQD := FALSE;
  158.             IF featureErr = noErr THEN
  159.                 BEGIN
  160.                     tempResult := BSR(tempResult, 8); { Shift the major version
  161.                                                        into the low byte }
  162.                     CASE tempResult OF
  163.                         1:
  164.                             gHasColorQD := TRUE;
  165.                         2:
  166.                             BEGIN
  167.                                 gHasColorQD := TRUE;
  168.                                 gHas32BitQD := TRUE;
  169.                             END;
  170.                     END;
  171.                 END;
  172.  
  173.             { Check for FindFolder.  Like with Gestalt, you can avoid this test
  174.               if you know your development environment provides glue for this
  175.               call like MPW 3.2 and later do. }
  176.             
  177.             gHasFindFolder := FALSE;
  178.             featureErr := Gestalt(gestaltFindFolderAttr, tempResult);
  179.             IF featureErr = noErr THEN
  180.                 gHasFindFolder := BTst(tempResult, gestaltFindFolderPresent);
  181.  
  182.             { Check for the DeviceLoop trap. }
  183.             
  184.             gHasDeviceLoop := TrapAvailable(_DeviceLoop);
  185.  
  186.             { Check for the Apple Events Manager.  You'll crash if you call it
  187.               when it's not implemented, such as under System 6.  }
  188.  
  189.             gHasAppleEvents := FALSE;
  190.             tempBit := gestaltAppleEventsPresent;
  191.             featureErr := Gestalt(gestaltAppleEventsAttr, tempResult);
  192.             IF featureErr = noErr THEN
  193.                 gHasAppleEvents := BTst(tempResult, tempBit);
  194.  
  195.             { Keep a copy of our application's resource file around.  Since we
  196.               call DetermineFeatures before doing any resource file 
  197.               manipulations, we're still the current resource file. }
  198.               
  199.               gAppsResourceFile := CurResFile;
  200.  
  201.             { Add more features here if you need them. }
  202.  
  203.         END; { if gHasGestalt then }
  204.  
  205.     DetermineFeatures := gHasGestalt; { We have no features if we have no Gestalt 
  206.                                         here. }
  207. END; {DetermineFeatures}
  208.